Leet-Translator | Quadropolis

Leetex | 2010-11-20 13:47

Leet-Translator

[

points ]

(2 votes)

Blurb Translate a text easily to leet-speak and share it with your friends

Detailed description

Do you know the leet-speak language? This is a language, in which you substitute numbers for letters, which look like a number. So the letter "A" would be replaced with "4" and so forth.

My script allows you to fill a text into a dynamic field and translates it into leet-speak.

Additional function: It's possible, to share the translated text with all the guys on the server or your teammates.

Info: Menu is bound to F1.

German version available on http://leetex.bplaced.net/leet-uebersetzer.php.

I know, the script isn't very useful, but it's just for fun. :-)

Preview

newgui "Leet-Translator" [
	guititle "Leet-Translator"
	guibar
		guitext "Set the width of the field: " 0
		guislider "width_of_field" "1" "128" [translate = (substr [@translate] 0 $width_of_field)]
	guibar
	guilist [
		guitext "Your text: " 0
		guifield "translate" $width_of_field "mustblink = 1; blink"
		guistayopen [
			guibar
			guibutton [@translate_button_text] [mustblink = 0; checknumber = 0; number = 0; stelle = 0; replace_string]
		]
	]
	guibar
	guitext "   ^f5Your leeted text:" 0
	guitext [@(result "^f7")@translate] 0
	guibar
	guilist [
		guistayopen [
			guibutton "^f0Say it!" [method = 1; check_empty] "snoutx10k"
			guibar
			guibutton "^f1Teamchat it!" [method = 0; check_empty] "snoutx10k_blue"
			guibar
			guibutton "^f3Close this window" [cleargui] "exit"
		]
	]
] "Leet-Translator"

newgui "warning" [
	guitext "Your translate-field is empty." 0
	guitext "Type a text to translate it." 0
	guibar
	guialign 0 [
	guibutton "OK" [showgui "Leet-Translator"] "exit"
	]
] "^f3Warning!"

check_empty = [if (strcmp [@translate] "") [showgui "warning"] [if $method [say [@translate]] [sayteam [@translate]] ]]

char = "O o I i Z z E e A a S s G g T t"
translate_button_text = "^f7Translate"
width_of_field = "64"

replace_string = [loop x 16 [
	translate = (strreplace $translate (substr [@char] $stelle 1) $number)
	stelle = (+ $stelle 2)
	checknumber = (+ $checknumber 1)
	if (mod $checknumber 2) [] [number = (+ $number 1)]
	]
]

blink = [if (= $mustblink 1) [translate_button_text = "^f7Translate"; sleep 500 [translate_button_text = "^f3Translate"; sleep 500 [blink]]] [translate_button_text = "^f7Translate"]]

bind "F1" [showgui "Leet-Translator"]
editbind "F1" [showgui "Leet-Translator"]

Config file leet.cfg (1.73 KB)

Rating

points

(2 votes)

Attachment	Size
leet.png	440.79 KB

Comments

Calinou | 2010-11-20 16:24

Lol ! So funny :D

RaZgRiZ | 2010-11-20 18:23

instead of "width_of_field" use a negative number for the size. that will allow it to expand if it needs to.

the warning gui is pretty much useless. use separated checks that will echo individual errors.

Blindabuser | 2010-11-20 20:08

Nice idea (things like these make me like Sauerbraten even more!)
It would be fun to have an automatic 1337 converter for chat console/system messages (a bit messy to read while playing, perhaps). :P

srbs | 2010-11-21 00:54

I kinda laughed at:
guitext [@(result "^f7")@translate] 0
alternatives that aren't so weird:
guitext [^f7@translate] 0 guitext (concatword "^f7" $translate) 0

Also, what is up with all of these:
[@translate]
just use:
$translate

srbs

Leetex | 2010-11-21 10:07

Yes, but the problem is, when I use $translate, there are sometimes more than 1 word. So when there are there three words for example, the software interpret this as three parameters and that leads to an error.

But thanks for your comment :)

srbs | 2010-11-21 11:08

Umm, lol?
No it doesn't.

However, it would if you had just @translate and no brackets inside of a command, it would.

srbs

Leetex | 2010-11-21 12:29

Okay, I noticed it. Thanks for the answer :)

SomeDude | 2010-11-22 04:39

Lol, I had this same idea once. Now I wish I'd actually made it. Kudos to you Leetex. XP

Though, I think I'd rather use it in a command-form rather than a gui one.
Like "/l33t leet speak test " or even "/say (l33t "leet speak test") "
It'd be much simpler.

Calinou | 2010-11-22 12:12

That's what Blindabuser said. I support you for this, make it Leetex :P

Leetex | 2010-11-22 20:11

I would, but (it's very painful) I don't know how to create commands with parameters. :(

srbs | 2010-11-22 20:59

There is a system for args, you have: $arg1 - $arg24 & $numargs and the command 'result'.

So, you would do something like:
leet = [ translated = $arg1 //do stuff with $translated result $translated ]

Then users can do:
/say (leet ..)

srbs

Nyne | 2014-04-29 16:26


// *** CubeScript: leet ***

leet = [
    local _leetchar _leetindex _leetcnum _leetnum _leetstr
    _leetchar = "O o I i Z z E e A a S s G g T t"
    _leetindex = 0
    _leetcnum = 0
    _leetnum = 0
    _leetstr = (loopconcat i $numargs [result $[arg@(+ $i 1)]])
    loop i 16 [
        _leetstr = (strreplace $_leetstr (substr [@_leetchar] $_leetindex 1) $_leetnum)
        _leetindex = (+ $_leetindex 2)
        _leetcnum = (+ $_leetcnum 1)
        if (! (mod $_leetcnum 2)) [_leetnum = (+ $_leetnum 1)]
    ]
    say $_leetstr
]

Syntax: »/leet hello world«

Nyne | 2014-05-02 01:20

Cooler:

bind "L" [saycommand "/leet "]

Nyne | 2014-06-22 18:47

I just leave this here:

leetspeak = [
    local _leetspeak_string _leetspeak_chars_upper _leetspeak_chars_lower _leetspeak_replacement
    _leetspeak_string = $arg1
    _leetspeak_chars_upper = ["A" "B" "C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "R" "S" "T" "U" "V" "W" "X" "Y" "Z"]
    _leetspeak_chars_lower = ["a" "b" "c" "d" "e" "f" "g" "h" "i" "j" "k" "l" "m" "n" "o" "p" "q" "r" "s" "t" "u" "v" "w" "x" "y" "z"]
    _leetspeak_replacement = ["4" "8" "(" "|)" "3" "PH" "6" "|-|" "!" "_|" "|>" "1" "/\/\" "/\/" "0" "9" "0_" "2" "5" "7" "|_|" "\/" "\/\/" "><" "`/" "Z"]
//  _leetspeak_replacement = ["д" "в" "с" "d" "ɛ" "f" "ɕ" "н" "i" "j" "к" "l" "м" "и" "ѳ" "p" "q" "я" "s" "т" "ц" "ѵ" "щ" "ж" "ч" "z"]
    loop i 26 [_leetspeak_string = (strreplace $_leetspeak_string (at $_leetspeak_chars_upper $i) (at $_leetspeak_replacement $i))]
    loop i 26 [_leetspeak_string = (strreplace $_leetspeak_string (at $_leetspeak_chars_lower $i) (at $_leetspeak_replacement $i))]
    say $_leetspeak_string
]

bind "L" [saycommand "/leetspeak "]

Suicizer | 2010-11-22 17:04

me liking it more in guitabs than command-formish...
Anyways, nice content! I like it ^^!

Papriko | 2014-05-05 12:41

Leetex makes a script for leetex(t)! I see what you did there!

User login

Navigation

Users on Quadropolis